Search Digital Narrative Knowledge Base Digital Narrative Knowledge Base

Explore the data

Ask questions about DNKB

Ask an AI assistant or run a query yourself. No account or SPARQL knowledge needed.

Ask your AI assistant

Use DNKB's data reference at https://dnkb.cdn.uib.no/docs/querying.md to answer: how many Flash artworks are in French? Run the SPARQL query if your tools support it; otherwise give me a query-service link I can run. Show the query, retrieval date, interpretation and missing-data limitations.
  1. Copy the prompt into your assistant. Change the question to your own.
  2. Check that it read the reference and ran the query.
  3. Got a query link? Open it and click Run to verify the answer.

Try the examples

Last checked 2026-11-02. Results come from the live dataset and can change.

Which 5 creative works are the most cited?

Counts distinct critical writings in DNKB that cite each creative work, not citations across the wider literature.

View SPARQL
PREFIX wd: <https://wbs.cdn.uib.no/entity/>
PREFIX wdt: <https://wbs.cdn.uib.no/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?work ?title ?citations WHERE {
  {
    SELECT ?work (COUNT(DISTINCT ?writing) AS ?citations) WHERE {
      ?work wdt:P1/wdt:P108* wd:Q7007 .
      ?writing wdt:P1/wdt:P108* wd:Q7008 ;
               wdt:P120 ?work .
    }
    GROUP BY ?work
    ORDER BY DESC(?citations) ?work
    LIMIT 5
  }
  OPTIONAL { ?work rdfs:label ?title . FILTER(LANG(?title) = "en") }
}
ORDER BY DESC(?citations) ?work

Top 10 journals by critical writing publications

Counts distinct critical writings linked to each academic journal through “published in”. Unlinked publications are excluded.

View SPARQL
PREFIX wd: <https://wbs.cdn.uib.no/entity/>
PREFIX wdt: <https://wbs.cdn.uib.no/prop/direct/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT ?journal ?title ?publications WHERE {
  {
    SELECT ?journal (COUNT(DISTINCT ?writing) AS ?publications) WHERE {
      ?journal wdt:P1/wdt:P108* wd:Q6783 .
      ?writing wdt:P1/wdt:P108* wd:Q7008 ;
               wdt:P7 ?journal .
    }
    GROUP BY ?journal
    ORDER BY DESC(?publications) ?journal
    LIMIT 10
  }
  OPTIONAL { ?journal rdfs:label ?title . FILTER(LANG(?title) = "en") }
}
ORDER BY DESC(?publications) ?journal

Data reference

Use DNKB’s local IDs, which differ from Wikidata’s. SPARQL endpoint: https://query.wbs.cdn.uib.no/sparql.

Prefixes, properties and items
PREFIX wd: <https://wbs.cdn.uib.no/entity/>
PREFIX wdt: <https://wbs.cdn.uib.no/prop/direct/>
PREFIX p: <https://wbs.cdn.uib.no/prop/>
PREFIX ps: <https://wbs.cdn.uib.no/prop/statement/>
PREFIX pq: <https://wbs.cdn.uib.no/prop/qualifier/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX wikibase: <http://wikiba.se/ontology#>
PREFIX bd: <http://www.bigdata.com/rdf#>

Common properties

IDPropertyMeaning
P1instance ofClass of an item; use P108 paths to include subclasses.
P108subclass ofClass hierarchy, from child to parent.
P6authorLinks a work to a person item.
P113author name stringA literal name, not a person item; person-based counts can omit these authors.
P10language of work or nameLanguage, not country of origin or citizenship.
P11country of originCountry recorded for a work.
P29publication dateUse YEAR() for grouping; dates can describe original publication rather than a software version.
P120cites workLinks a citing critical writing to the cited work.
P7published inLinks a writing to its journal or other containing publication.
P86software engineThe property used to link works to Adobe Flash and Twine.
P100programmed inDo not assume this is the property used for authoring software; inspect actual statements.
P3Wikidata entity identifierExternal Wikidata identifier; local Q/P IDs have different meanings.

Common items